Collaboration Data Objects (CDO) 1.1 supports programmatic access to MAPI Address Books through the AddressEntries collection of an AddressList object. Each AddressList object corresponds to a MAPI Address Book and is a member of the AddressLists collection of the Session object.

The available Address Books can be enumerated by walking the AddressLists collection, and an individual address book can be selected by indexing the AddressLists collection by name or by position.

The following sample code walks the AddressLists collection, and displays information about each address book that can be accessed. The second part of the sample selects the global address list (GAL) and then walks the Address Entries, recursively expanding Distribution Lists.

The following sample code applies to any 32-bit Visual Basic-based product.

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

Step-by-step example

1. Create a new Visual Basic project. Add a reference to the Collaboration Data Objects 1.1 Object Library.
2. Type the following code into a module.

         Option Explicit
   
         Sub main()
   
             Dim objSession As MAPI.Session        ' Use early binding for
                                                   ' efficiency.
             Dim collAddressLists As AddressLists
             Dim objAddressList As AddressList
             Dim collAddressEntries As AddressEntries
   
             On Error GoTo error_olemsg
   
             ' Create a session and log on.
             Set objSession = CreateObject("MAPI.Session")
             ' Use a valid Exchange profile name.
             objSession.Logon ("<Your Profile Name Here>")
   
             'Walk the available address books.
             Set collAddressLists = objSession.AddressLists
             For Each objAddressList In collAddressLists
                  ' Display collection selection indices.
                  Debug.Print objAddressList.Name,
                  Debug.Print objAddressList.Index,
                  ' Display the readonly access flag.
                  Debug.Print objAddressList.IsReadOnly,
   
                  ' Display the count of recipients.
                  Set collAddressEntries = objAddressList.AddressEntries
                  Debug.Print Str(collAddressEntries.Count)
                  ' If there are any AddressEntries, display the first recipient name.
                  If Not objAddressList.AddressEntries(1) Is Nothing Then _
                       Debug.Print objAddressList.AddressEntries(1).Name
   
             Next objAddressList
   
             ' Walk the global address list.
             Set collAddressEntries = objSession.AddressLists( _
                      "Global Address List").AddressEntries
             WalkAddressList collAddressEntries
   
             ' Close the session and log off.
             objSession.Logoff
             Exit Sub
   
         error_olemsg:
                  MsgBox "Error " & Str(Err) & ": " & Error$(Err)
                  Exit Sub
   
         End Sub
   
         ' Walk an AddressEntries collection and recursively expand
         ' Distribution Lists.
   
         Sub WalkAddressList(collAddressEntries As AddressEntries)
             Dim objaddressEntry As AddressEntry
   
             For Each objaddressEntry In collAddressEntries
                  ' Display the recipient's name.
                  Debug.Print objaddressEntry.Name,
                  ' Display the recipient's type.
                  Select Case objaddressEntry.DisplayType
                  Case ActMsgUser
                      Debug.Print "Exchange Recipient"
                  Case ActMsgDistList
                      Debug.Print "Distribution List"
                      WalkAddressList objaddressEntry.Members
                      Debug.Print "End of DL " & objaddressEntry.Name
                  Case ActMsgForum
                      Debug.Print "Public Folder"
                  Case ActMsgAgent
                      Debug.Print "Agent"
                  Case ActMsgPrivateDistList
                      Debug.Print "Private DL"
                  Case ActMsgOrganization
                      Debug.Print "Organization"
                  Case ActMsgRemoteUser
                      Debug.Print "Custom Recipient"
                  Case Else
                      Debug.Print "Unknown type"
                  End Select
   
             Next objaddressEntry
   
         End Sub

3. Visual Basic only: Set Sub Main to run in the Project Properties, and then run the application.
   
   Other VBA applications: In the Debug/Immediate window, type MAIN, and then press ENTER. The output will appear in the Debug/Immediate window.

Notes

The address book can have restricted entries. Restricted entries will generate an "Access Denied" message: The user can include additional error handling where required.

Documentation for Active Messaging is available in the Microsoft Developer Network (MSDN) Library under the following topics:

• SDK Documentation
• Platform SDK
• Databases and Messaging Services
• Active Messaging

For more information about how to obtain Collaboration Data Objects Libraries, click the following article number to view the article in the Microsoft Knowledge Base: